b9d0556c84
made to the sb_oltp.c and sb_oltp.h files (those changes will be merged at a later date). -added drizzle support to lua tests -removed some dead code -updated autotools system -Added extensions.m4 -Removed manual.html - it's generated -Turned on warnings. Made sysbench compile with them on -Added support for building with libdrizzle -Added run.sh as example of how to run drizzle sys-bench -drv drizzle works with multi-thread -drv_drizzle: misc. fixes -drv_drizzle: fix all four buffering forms -Checking for error codes using new clean method. -Check that new constant exists in autoconf -drv_drizzle: Turned unsigned ints back off -drv_drizzle: Updated error fetching code -drv_drizzle: Removed blocking option - makes no sense. Cleaned up option help text -Up to date with latest libdrizzle changes -fixed some solaris build issues -Split acinclude into multiple files in m4/ dir -downgraded autoconf -Removed -Wlogical-op, it's only in newer GCC, and it's not important enough to impose GCC version restrictions for -Removed need for drizzled install for libdrizzle build -Fixed solaris build issues -Fixed new libdrizzle result processing -Added the all_need_caps explicitly to drv_mysql -Added capability for libdrizzle
38 lines
1.1 KiB
Plaintext
38 lines
1.1 KiB
Plaintext
dnl Provide AC_USE_SYSTEM_EXTENSIONS for old autoconf machines.
|
|
AC_DEFUN([ACX_USE_SYSTEM_EXTENSIONS],[
|
|
ifdef([AC_USE_SYSTEM_EXTENSIONS],[
|
|
AC_USE_SYSTEM_EXTENSIONS
|
|
],[
|
|
AC_BEFORE([$0], [AC_COMPILE_IFELSE])
|
|
AC_BEFORE([$0], [AC_RUN_IFELSE])
|
|
|
|
AC_REQUIRE([AC_GNU_SOURCE])
|
|
AC_REQUIRE([AC_AIX])
|
|
AC_REQUIRE([AC_MINIX])
|
|
|
|
AH_VERBATIM([__EXTENSIONS__],
|
|
[/* Enable extensions on Solaris. */
|
|
#ifndef __EXTENSIONS__
|
|
# undef __EXTENSIONS__
|
|
#endif
|
|
#ifndef _POSIX_PTHREAD_SEMANTICS
|
|
# undef _POSIX_PTHREAD_SEMANTICS
|
|
#endif
|
|
#ifndef _TANDEM_SOURCE
|
|
# undef _TANDEM_SOURCE
|
|
#endif])
|
|
AC_CACHE_CHECK([whether it is safe to define __EXTENSIONS__],
|
|
[ac_cv_safe_to_define___extensions__],
|
|
[AC_COMPILE_IFELSE(
|
|
[AC_LANG_PROGRAM([
|
|
# define __EXTENSIONS__ 1
|
|
AC_INCLUDES_DEFAULT])],
|
|
[ac_cv_safe_to_define___extensions__=yes],
|
|
[ac_cv_safe_to_define___extensions__=no])])
|
|
test $ac_cv_safe_to_define___extensions__ = yes &&
|
|
AC_DEFINE([__EXTENSIONS__])
|
|
AC_DEFINE([_POSIX_PTHREAD_SEMANTICS])
|
|
AC_DEFINE([_TANDEM_SOURCE])
|
|
])
|
|
])
|