Expose RTCDtmfSender API via RTCRtpSender in ObjC SDK.

Expose RTCDtmfSender API for ObcC SDK via exising RTCRtpSender
to provide ability to use DTMF tones in ObjC apps which uses WebRTC.
Android SDK has already exposed DTMF API via Java's DtmfSender
object, there changes provide similar functionaly to ObjC SDK.

Bug: webrtc:8713
Change-Id: Id68fddbbc362211dc8032fa31b38812d1cff8ed9
Reviewed-on: https://webrtc-review.googlesource.com/35800
Commit-Queue: Taylor Brandstetter <deadbeef@webrtc.org>
Reviewed-by: Taylor Brandstetter <deadbeef@webrtc.org>
Reviewed-by: Magnus Jedvert <magjed@webrtc.org>
Cr-Commit-Position: refs/heads/master@{#21505}

sdk/objc/Framework/Classes/PeerConnection/RTCDtmfSender+Private.h

@@ -0,0 +1,29 @@
+/*
+ *  Copyright 2017 The WebRTC project authors. All Rights Reserved.
+ *
+ *  Use of this source code is governed by a BSD-style license
+ *  that can be found in the LICENSE file in the root of the source
+ *  tree. An additional intellectual property rights grant can be found
+ *  in the file PATENTS.  All contributing project authors may
+ *  be found in the AUTHORS file in the root of the source tree.
+ */
+
+#import "WebRTC/RTCDtmfSender.h"
+
+#include "api/dtmfsenderinterface.h"
+
+NS_ASSUME_NONNULL_BEGIN
+
+@interface RTCDtmfSender : NSObject <RTCDtmfSender>
+
+@property(nonatomic, readonly) rtc::scoped_refptr<webrtc::DtmfSenderInterface> nativeDtmfSender;
+
+- (instancetype)init NS_UNAVAILABLE;
+
+/** Initialize an RTCDtmfSender with a native DtmfSenderInterface. */
+- (instancetype)initWithNativeDtmfSender:
+        (rtc::scoped_refptr<webrtc::DtmfSenderInterface>)nativeDtmfSender NS_DESIGNATED_INITIALIZER;
+
+@end
+
+NS_ASSUME_NONNULL_END

sdk/objc/Framework/Classes/PeerConnection/RTCDtmfSender.mm

@@ -0,0 +1,74 @@
+/*
+ *  Copyright 2017 The WebRTC project authors. All Rights Reserved.
+ *
+ *  Use of this source code is governed by a BSD-style license
+ *  that can be found in the LICENSE file in the root of the source
+ *  tree. An additional intellectual property rights grant can be found
+ *  in the file PATENTS.  All contributing project authors may
+ *  be found in the AUTHORS file in the root of the source tree.
+ */
+
+#import "RTCDtmfSender+Private.h"
+
+#import "NSString+StdString.h"
+#import "WebRTC/RTCLogging.h"
+
+#include "rtc_base/timeutils.h"
+
+@implementation RTCDtmfSender {
+  rtc::scoped_refptr<webrtc::DtmfSenderInterface> _nativeDtmfSender;
+}
+
+- (BOOL)canInsertDtmf {
+  return _nativeDtmfSender->CanInsertDtmf();
+}
+
+- (BOOL)insertDtmf:(nonnull NSString *)tones
+          duration:(NSTimeInterval)duration
+      interToneGap:(NSTimeInterval)interToneGap {
+  RTC_DCHECK(tones != nil);
+
+  int durationMs = static_cast<int>(duration * rtc::kNumMillisecsPerSec);
+  int interToneGapMs = static_cast<int>(interToneGap * rtc::kNumMillisecsPerSec);
+  return _nativeDtmfSender->InsertDtmf(
+      [NSString stdStringForString:tones], durationMs, interToneGapMs);
+}
+
+- (nonnull NSString *)remainingTones {
+  return [NSString stringForStdString:_nativeDtmfSender->tones()];
+}
+
+- (NSTimeInterval)duration {
+  return static_cast<NSTimeInterval>(_nativeDtmfSender->duration()) / rtc::kNumMillisecsPerSec;
+}
+
+- (NSTimeInterval)interToneGap {
+  return static_cast<NSTimeInterval>(_nativeDtmfSender->inter_tone_gap()) /
+      rtc::kNumMillisecsPerSec;
+}
+
+- (NSString *)description {
+  return [NSString
+      stringWithFormat:
+          @"RTCDtmfSender {\n  remainingTones: %@\n  duration: %f sec\n  interToneGap: %f sec\n}",
+          [self remainingTones],
+          [self duration],
+          [self interToneGap]];
+}
+
+#pragma mark - Private
+
+- (rtc::scoped_refptr<webrtc::DtmfSenderInterface>)nativeDtmfSender {
+  return _nativeDtmfSender;
+}
+
+- (instancetype)initWithNativeDtmfSender:
+        (rtc::scoped_refptr<webrtc::DtmfSenderInterface>)nativeDtmfSender {
+  NSParameterAssert(nativeDtmfSender);
+  if (self = [super init]) {
+    _nativeDtmfSender = nativeDtmfSender;
+    RTCLogInfo(@"RTCDtmfSender(%p): created DTMF sender: %@", self, self.description);
+  }
+  return self;
+}
+@end

sdk/objc/Framework/Classes/PeerConnection/RTCRtpSender.mm

@@ -11,6 +11,7 @@
 #import "RTCRtpSender+Private.h"
 
 #import "NSString+StdString.h"
+#import "RTCDtmfSender+Private.h"
 #import "RTCMediaStreamTrack+Private.h"
 #import "RTCRtpParameters+Private.h"
 #import "WebRTC/RTCLogging.h"
@@ -21,6 +22,8 @@
   rtc::scoped_refptr<webrtc::RtpSenderInterface> _nativeRtpSender;
 }
 
+@synthesize dtmfSender = _dtmfSender;
+
 - (NSString *)senderId {
   return [NSString stringForStdString:_nativeRtpSender->id()];
 }
@@ -86,6 +89,11 @@
   NSParameterAssert(nativeRtpSender);
   if (self = [super init]) {
     _nativeRtpSender = nativeRtpSender;
+    rtc::scoped_refptr<webrtc::DtmfSenderInterface> nativeDtmfSender(
+        _nativeRtpSender->GetDtmfSender());
+    if (nativeDtmfSender) {
+      _dtmfSender = [[RTCDtmfSender alloc] initWithNativeDtmfSender:nativeDtmfSender];
+    }
     RTCLogInfo(@"RTCRtpSender(%p): created sender: %@", self, self.description);
   }
   return self;