Add new Logger to iOS SDK to be able to intercept logs and report them to the appropriate system

Bug: webrtc:8695
Change-Id: I4f81529222dcaf3dded1a0ab93fabf5cda1fdef8
Reviewed-on: https://webrtc-review.googlesource.com/37001
Reviewed-by: Kári Helgason <kthelgason@webrtc.org>
Reviewed-by: Anders Carlsson <andersc@webrtc.org>
Commit-Queue: Kári Helgason <kthelgason@webrtc.org>
Cr-Commit-Position: refs/heads/master@{#21821}

sdk/BUILD.gn

@@ -84,7 +84,9 @@ if (is_ios || is_mac) {
 
     if (!build_with_chromium) {
       sources += [
+        "objc/Framework/Classes/Common/RTCCallbackLogger.mm",
         "objc/Framework/Classes/Common/RTCFileLogger.mm",
+        "objc/Framework/Headers/WebRTC/RTCCallbackLogger.h",
         "objc/Framework/Headers/WebRTC/RTCFileLogger.h",
       ]
     }
@@ -596,6 +598,7 @@ if (is_ios || is_mac) {
           ]
 
           sources = [
+            "objc/Framework/UnitTests/RTCCallbackLogger_xctest.m",
             "objc/Framework/UnitTests/RTCDoNotPutCPlusPlusInFrameworkHeaders_xctest.m",
             "objc/Framework/UnitTests/RTCFileVideoCapturer_xctest.mm",
           ]
@@ -785,8 +788,14 @@ if (is_ios || is_mac) {
         public_headers = common_objc_headers
 
         if (!build_with_chromium) {
-          sources += [ "objc/Framework/Headers/WebRTC/RTCFileLogger.h" ]
+          sources += [
-          public_headers += [ "objc/Framework/Headers/WebRTC/RTCFileLogger.h" ]
+            "objc/Framework/Headers/WebRTC/RTCCallbackLogger.h",
+            "objc/Framework/Headers/WebRTC/RTCFileLogger.h",
+          ]
+          public_headers += [
+            "objc/Framework/Headers/WebRTC/RTCCallbackLogger.h",
+            "objc/Framework/Headers/WebRTC/RTCFileLogger.h",
+          ]
         }
 
         ldflags = [

sdk/objc/Framework/Classes/Common/RTCCallbackLogger.mm

@@ -0,0 +1,84 @@
+/*
+ *  Copyright 2018 The WebRTC project authors. All Rights Reserved.
+ *
+ *  Use of this source code is governed by a BSD-style license
+ *  that can be found in the LICENSE file in the root of the source
+ *  tree. An additional intellectual property rights grant can be found
+ *  in the file PATENTS.  All contributing project authors may
+ *  be found in the AUTHORS file in the root of the source tree.
+ */
+
+#import "WebRTC/RTCCallbackLogger.h"
+
+#include <memory>
+
+#include "rtc_base/checks.h"
+#include "rtc_base/logging.h"
+#include "rtc_base/logsinks.h"
+
+class CallbackLogSink : public rtc::LogSink {
+ public:
+  CallbackLogSink(void (^callbackHandler)(NSString *message)) {
+    callback_handler_ = callbackHandler;
+  }
+
+  ~CallbackLogSink() override { callback_handler_ = nil; }
+
+  void OnLogMessage(const std::string &message) override {
+    if (callback_handler_) {
+      callback_handler_([NSString stringWithUTF8String:message.c_str()]);
+    }
+  }
+
+ private:
+  void (^callback_handler_)(NSString *message);
+};
+
+@implementation RTCCallbackLogger {
+  BOOL _hasStarted;
+  std::unique_ptr<CallbackLogSink> _logSink;
+}
+
+@synthesize severity = _severity;
+
+- (void)dealloc {
+  [self stop];
+}
+
+- (void)start:(nullable void (^)(NSString *))callback {
+  if (_hasStarted) {
+    return;
+  }
+
+  _logSink.reset(new CallbackLogSink(callback));
+
+  rtc::LogMessage::AddLogToStream(_logSink.get(), [self rtcSeverity]);
+  _hasStarted = YES;
+}
+
+- (void)stop {
+  if (!_hasStarted) {
+    return;
+  }
+  RTC_DCHECK(_logSink);
+  rtc::LogMessage::RemoveLogToStream(_logSink.get());
+  _hasStarted = NO;
+  _logSink.reset();
+}
+
+#pragma mark - Private
+
+- (rtc::LoggingSeverity)rtcSeverity {
+  switch (_severity) {
+    case RTCLoggingSeverityVerbose:
+      return rtc::LS_VERBOSE;
+    case RTCLoggingSeverityInfo:
+      return rtc::LS_INFO;
+    case RTCLoggingSeverityWarning:
+      return rtc::LS_WARNING;
+    case RTCLoggingSeverityError:
+      return rtc::LS_ERROR;
+  }
+}
+
+@end

sdk/objc/Framework/Headers/WebRTC/RTCCallbackLogger.h

@@ -0,0 +1,35 @@
+/*
+ *  Copyright 2018 The WebRTC project authors. All Rights Reserved.
+ *
+ *  Use of this source code is governed by a BSD-style license
+ *  that can be found in the LICENSE file in the root of the source
+ *  tree. An additional intellectual property rights grant can be found
+ *  in the file PATENTS.  All contributing project authors may
+ *  be found in the AUTHORS file in the root of the source tree.
+ */
+
+#import <Foundation/Foundation.h>
+
+#import <WebRTC/RTCLogging.h>
+#import <WebRTC/RTCMacros.h>
+
+NS_ASSUME_NONNULL_BEGIN
+
+// This class intercepts WebRTC logs and forwards them to a registered block.
+// This class is not threadsafe.
+RTC_EXPORT
+@interface RTCCallbackLogger : NSObject
+
+// The severity level to capture. The default is kRTCLoggingSeverityInfo.
+@property(nonatomic, assign) RTCLoggingSeverity severity;
+
+// The callback will be called on the same thread that does the logging, so
+// if the logging callback can be slow it may be a good idea to implement
+// dispatching to some other queue.
+- (void)start:(nullable void (^)(NSString*))callback;
+
+- (void)stop;
+
+@end
+
+NS_ASSUME_NONNULL_END

sdk/objc/Framework/UnitTests/RTCCallbackLogger_xctest.m

@@ -0,0 +1,103 @@
+/*
+ *  Copyright 2018 The WebRTC project authors. All Rights Reserved.
+ *
+ *  Use of this source code is governed by a BSD-style license
+ *  that can be found in the LICENSE file in the root of the source
+ *  tree. An additional intellectual property rights grant can be found
+ *  in the file PATENTS.  All contributing project authors may
+ *  be found in the AUTHORS file in the root of the source tree.
+ */
+
+#import "WebRTC/RTCCallbackLogger.h"
+
+#import <XCTest/XCTest.h>
+
+@interface RTCCallbackLoggerTests : XCTestCase
+
+@property(nonatomic, strong) RTCCallbackLogger *logger;
+
+@end
+
+@implementation RTCCallbackLoggerTests
+
+@synthesize logger;
+
+- (void)setUp {
+  self.logger = [[RTCCallbackLogger alloc] init];
+}
+
+- (void)tearDown {
+  self.logger = nil;
+}
+
+- (void)testCallbackGetsCalledForAppropriateLevel {
+  self.logger.severity = RTCLoggingSeverityWarning;
+
+  XCTestExpectation *callbackExpectation = [self expectationWithDescription:@"callbackWarning"];
+
+  [self.logger start:^(NSString *message) {
+    XCTAssertTrue([message hasSuffix:@"Horrible error\n"]);
+    [callbackExpectation fulfill];
+  }];
+
+  RTCLogError("Horrible error");
+
+  [self waitForExpectations:@[ callbackExpectation ] timeout:10.0];
+}
+
+- (void)testCallbackDoesNotGetCalledForOtherLevels {
+  self.logger.severity = RTCLoggingSeverityError;
+
+  XCTestExpectation *callbackExpectation = [self expectationWithDescription:@"callbackError"];
+
+  [self.logger start:^(NSString *message) {
+    XCTAssertTrue([message hasSuffix:@"Horrible error\n"]);
+    [callbackExpectation fulfill];
+  }];
+
+  RTCLogInfo("Just some info");
+  RTCLogWarning("Warning warning");
+  RTCLogError("Horrible error");
+
+  [self waitForExpectations:@[ callbackExpectation ] timeout:10.0];
+}
+
+- (void)testStartingWithNilCallbackDoesNotCrash {
+  [self.logger start:nil];
+
+  RTCLogError("Horrible error");
+}
+
+- (void)testStopCallbackLogger {
+  XCTestExpectation *callbackExpectation = [self expectationWithDescription:@"stopped"];
+
+  [self.logger start:^(NSString *message) {
+    [callbackExpectation fulfill];
+  }];
+
+  [self.logger stop];
+
+  RTCLogInfo("Just some info");
+
+  XCTWaiter *waiter = [[XCTWaiter alloc] init];
+  XCTWaiterResult result = [waiter waitForExpectations:@[ callbackExpectation ] timeout:1.0];
+  XCTAssertEqual(result, XCTWaiterResultTimedOut);
+}
+
+- (void)testDestroyingCallbackLogger {
+  XCTestExpectation *callbackExpectation = [self expectationWithDescription:@"destroyed"];
+
+  [self.logger start:^(NSString *message) {
+    [callbackExpectation fulfill];
+  }];
+
+  self.logger = nil;
+
+  RTCLogInfo("Just some info");
+
+  XCTWaiter *waiter = [[XCTWaiter alloc] init];
+  XCTWaiterResult result = [waiter waitForExpectations:@[ callbackExpectation ] timeout:1.0];
+  XCTAssertEqual(result, XCTWaiterResultTimedOut);
+}
+
+@end