Update/move RTCVideoRendererAdapter to webrtc/api/objc.

BUG=
R=tkchin@webrtc.org

Review URL: https://codereview.webrtc.org/1533323003 .

Patch from Jon Hjelle <hjon@andyet.net>.

Cr-Commit-Position: refs/heads/master@{#11347}

webrtc/api/BUILD.gn

@@ -59,6 +59,9 @@ if (is_ios) {
       "objc/RTCVideoFrame.h",
       "objc/RTCVideoFrame.mm",
       "objc/RTCVideoRenderer.h",
+      "objc/RTCVideoRendererAdapter+Private.h",
+      "objc/RTCVideoRendererAdapter.h",
+      "objc/RTCVideoRendererAdapter.mm",
       "objc/WebRTC-Prefix.pch",
     ]
 

webrtc/api/api.gyp

@@ -46,6 +46,9 @@
             'objc/RTCVideoFrame.h',
             'objc/RTCVideoFrame.mm',
             'objc/RTCVideoRenderer.h',
+            'objc/RTCVideoRendererAdapter+Private.h',
+            'objc/RTCVideoRendererAdapter.h',
+            'objc/RTCVideoRendererAdapter.mm',
             'objc/RTCVideoSource+Private.h',
             'objc/RTCVideoSource.h',
             'objc/RTCVideoSource.mm',

webrtc/api/objc/RTCVideoRendererAdapter+Private.h

@@ -0,0 +1,42 @@
+/*
+ *  Copyright 2015 The WebRTC project authors. All Rights Reserved.
+ *
+ *  Use of this source code is governed by a BSD-style license
+ *  that can be found in the LICENSE file in the root of the source
+ *  tree. An additional intellectual property rights grant can be found
+ *  in the file PATENTS.  All contributing project authors may
+ *  be found in the AUTHORS file in the root of the source tree.
+ */
+
+#import "RTCVideoRendererAdapter.h"
+
+#include "talk/app/webrtc/mediastreaminterface.h"
+
+#import "RTCVideoRenderer.h"
+
+NS_ASSUME_NONNULL_BEGIN
+
+@interface RTCVideoRendererAdapter ()
+
+/**
+ * The Objective-C video renderer passed to this adapter during construction.
+ * Calls made to the webrtc::VideoRenderInterface will be adapted and passed to
+ * this video renderer.
+ */
+@property(nonatomic, readonly) id<RTCVideoRenderer> videoRenderer;
+
+/**
+ * The native VideoRendererInterface surface exposed by this adapter. Calls made
+ * to this interface will be adapted and passed to the RTCVideoRenderer supplied
+ * during construction. This pointer is unsafe and owned by this class.
+ */
+@property(nonatomic, readonly)
+    webrtc::VideoRendererInterface *nativeVideoRenderer;
+
+/** Initialize an RTCVideoRendererAdapter with an RTCVideoRenderer. */
+- (instancetype)initWithNativeRenderer:(id<RTCVideoRenderer>)videoRenderer
+    NS_DESIGNATED_INITIALIZER;
+
+@end
+
+NS_ASSUME_NONNULL_END

webrtc/api/objc/RTCVideoRendererAdapter.h

@@ -0,0 +1,27 @@
+/*
+ *  Copyright 2015 The WebRTC project authors. All Rights Reserved.
+ *
+ *  Use of this source code is governed by a BSD-style license
+ *  that can be found in the LICENSE file in the root of the source
+ *  tree. An additional intellectual property rights grant can be found
+ *  in the file PATENTS.  All contributing project authors may
+ *  be found in the AUTHORS file in the root of the source tree.
+ */
+
+#import <Foundation/Foundation.h>
+
+NS_ASSUME_NONNULL_BEGIN
+
+/*
+ * Creates a webrtc::VideoRendererInterface surface for an RTCVideoRenderer. The
+ * webrtc::VideoRendererInterface is used by WebRTC rendering code - this
+ * adapter adapts calls made to that interface to the RTCVideoRenderer supplied
+ * during construction.
+ */
+@interface RTCVideoRendererAdapter : NSObject
+
+- (instancetype)init NS_UNAVAILABLE;
+
+@end
+
+NS_ASSUME_NONNULL_END

webrtc/api/objc/RTCVideoRendererAdapter.mm

@@ -0,0 +1,63 @@
+/*
+ *  Copyright 2015 The WebRTC project authors. All Rights Reserved.
+ *
+ *  Use of this source code is governed by a BSD-style license
+ *  that can be found in the LICENSE file in the root of the source
+ *  tree. An additional intellectual property rights grant can be found
+ *  in the file PATENTS.  All contributing project authors may
+ *  be found in the AUTHORS file in the root of the source tree.
+ */
+
+#import "RTCVideoRendererAdapter.h"
+
+#import "webrtc/api/objc/RTCVideoFrame+Private.h"
+#import "webrtc/api/objc/RTCVideoRendererAdapter+Private.h"
+
+namespace webrtc {
+
+class VideoRendererAdapter : public VideoRendererInterface {
+ public:
+  VideoRendererAdapter(RTCVideoRendererAdapter* adapter) {
+    adapter_ = adapter;
+    size_ = CGSizeZero;
+  }
+
+  void RenderFrame(const cricket::VideoFrame *nativeVideoFrame) override {
+    const cricket::VideoFrame *frame =
+        nativeVideoFrame->GetCopyWithRotationApplied();
+    CGSize current_size = CGSizeMake(frame->GetWidth(), frame->GetHeight());
+    if (!CGSizeEqualToSize(size_, current_size)) {
+      size_ = current_size;
+      [adapter_.videoRenderer setSize:size_];
+    }
+    RTCVideoFrame *videoFrame =
+        [[RTCVideoFrame alloc] initWithNativeFrame:frame];
+    [adapter_.videoRenderer renderFrame:videoFrame];
+  }
+
+ private:
+  __weak RTCVideoRendererAdapter *adapter_;
+  CGSize size_;
+};
+}
+
+@implementation RTCVideoRendererAdapter {
+  rtc::scoped_ptr<webrtc::VideoRendererAdapter> _adapter;
+}
+
+@synthesize videoRenderer = _videoRenderer;
+
+- (instancetype)initWithNativeRenderer:(id<RTCVideoRenderer>)videoRenderer {
+  NSParameterAssert(videoRenderer);
+  if (self = [super init]) {
+    _videoRenderer = videoRenderer;
+    _adapter.reset(new webrtc::VideoRendererAdapter(self));
+  }
+  return self;
+}
+
+- (webrtc::VideoRendererInterface *)nativeVideoRenderer {
+  return _adapter.get();
+}
+
+@end