# Copyright (c) 2014 The WebRTC project authors. All Rights Reserved.
#
# Use of this source code is governed by a BSD-style license
# that can be found in the LICENSE file in the root of the source
# tree. An additional intellectual property rights grant can be found
# in the file PATENTS.  All contributing project authors may
# be found in the AUTHORS file in the root of the source tree.

import("../../webrtc.gni")

config("audio_conference_mixer_config") {
  visibility = [ ":*" ]  # Only targets in this file can depend on this.
  include_dirs = [
    "include",
    "../include",
  ]
}

rtc_static_library("audio_conference_mixer") {
  sources = [
    "include/audio_conference_mixer.h",
    "include/audio_conference_mixer_defines.h",
    "source/audio_conference_mixer_impl.cc",
    "source/audio_conference_mixer_impl.h",
    "source/audio_frame_manipulator.cc",
    "source/audio_frame_manipulator.h",
    "source/memory_pool.h",
    "source/memory_pool_posix.h",
    "source/memory_pool_win.h",
    "source/time_scheduler.cc",
    "source/time_scheduler.h",
  ]

  public_configs = [ ":audio_conference_mixer_config" ]

  if (!build_with_chromium && is_clang) {
    # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
    suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
  }

  deps = [
    "..:module_api",
    "../..:webrtc_common",
    "../../audio/utility:audio_frame_operations",
    "../../rtc_base:rtc_base_approved",
    "../../system_wrappers",
    "../audio_processing",
  ]
}

if (rtc_include_tests) {
  rtc_source_set("audio_conference_mixer_unittests") {
    testonly = true

    # Skip restricting visibility on mobile platforms since the tests on those
    # gets additional generated targets which would require many lines here to
    # cover (which would be confusing to read and hard to maintain).
    if (!is_android && !is_ios) {
      visibility = [ "..:modules_unittests" ]
    }
    sources = [
      "test/audio_conference_mixer_unittest.cc",
    ]
    deps = [
      ":audio_conference_mixer",
      "../../test:test_support",
      "//testing/gmock",
    ]
    if (is_win) {
      cflags = [
        # TODO(kjellander): bugs.webrtc.org/261: Fix this warning.
        "/wd4373",  # virtual function override.
      ]
    }
    if (!build_with_chromium && is_clang) {
      # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
      suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
    }
  }
}