8d95e3b211
This change forks the existing iOS audio device module and audio device from modules/audio_device/ into sdk/objc/Framework. It also updates RTCPeerConnectionFactory to use the forked implementation. The unit tests are re-implemented as XCTests. (was: https://webrtc-review.googlesource.com/c/src/+/67300) Bug: webrtc:9120 Change-Id: I46c09900246f75ca5285aeb38f7b8b295784ffac Reviewed-on: https://webrtc-review.googlesource.com/76741 Reviewed-by: Kári Helgason <kthelgason@webrtc.org> Reviewed-by: Henrik Andreassson <henrika@webrtc.org> Reviewed-by: Anders Carlsson <andersc@webrtc.org> Commit-Queue: Peter Hanspers <peterhanspers@webrtc.org> Cr-Commit-Position: refs/heads/master@{#23238}
90 lines
3.0 KiB
Plaintext
90 lines
3.0 KiB
Plaintext
/*
|
|
* Copyright 2018 The WebRTC Project Authors. All rights reserved.
|
|
*
|
|
* Use of this source code is governed by a BSD-style license
|
|
* that can be found in the LICENSE file in the root of the source
|
|
* tree. An additional intellectual property rights grant can be found
|
|
* in the file PATENTS. All contributing project authors may
|
|
* be found in the AUTHORS file in the root of the source tree.
|
|
*/
|
|
|
|
#import "RTCNativeAudioSessionDelegateAdapter.h"
|
|
|
|
#include "sdk/objc/Framework/Native/src/audio/audio_session_observer.h"
|
|
|
|
#import "WebRTC/RTCLogging.h"
|
|
|
|
@implementation RTCNativeAudioSessionDelegateAdapter {
|
|
webrtc::AudioSessionObserver *_observer;
|
|
}
|
|
|
|
- (instancetype)initWithObserver:(webrtc::AudioSessionObserver *)observer {
|
|
RTC_DCHECK(observer);
|
|
if (self = [super init]) {
|
|
_observer = observer;
|
|
}
|
|
return self;
|
|
}
|
|
|
|
#pragma mark - RTCAudioSessionDelegate
|
|
|
|
- (void)audioSessionDidBeginInterruption:(RTCAudioSession *)session {
|
|
_observer->OnInterruptionBegin();
|
|
}
|
|
|
|
- (void)audioSessionDidEndInterruption:(RTCAudioSession *)session
|
|
shouldResumeSession:(BOOL)shouldResumeSession {
|
|
_observer->OnInterruptionEnd();
|
|
}
|
|
|
|
- (void)audioSessionDidChangeRoute:(RTCAudioSession *)session
|
|
reason:(AVAudioSessionRouteChangeReason)reason
|
|
previousRoute:(AVAudioSessionRouteDescription *)previousRoute {
|
|
switch (reason) {
|
|
case AVAudioSessionRouteChangeReasonUnknown:
|
|
case AVAudioSessionRouteChangeReasonNewDeviceAvailable:
|
|
case AVAudioSessionRouteChangeReasonOldDeviceUnavailable:
|
|
case AVAudioSessionRouteChangeReasonCategoryChange:
|
|
// It turns out that we see a category change (at least in iOS 9.2)
|
|
// when making a switch from a BT device to e.g. Speaker using the
|
|
// iOS Control Center and that we therefore must check if the sample
|
|
// rate has changed. And if so is the case, restart the audio unit.
|
|
case AVAudioSessionRouteChangeReasonOverride:
|
|
case AVAudioSessionRouteChangeReasonWakeFromSleep:
|
|
case AVAudioSessionRouteChangeReasonNoSuitableRouteForCategory:
|
|
_observer->OnValidRouteChange();
|
|
break;
|
|
case AVAudioSessionRouteChangeReasonRouteConfigurationChange:
|
|
// The set of input and output ports has not changed, but their
|
|
// configuration has, e.g., a port’s selected data source has
|
|
// changed. Ignore this type of route change since we are focusing
|
|
// on detecting headset changes.
|
|
RTCLog(@"Ignoring RouteConfigurationChange");
|
|
break;
|
|
}
|
|
}
|
|
|
|
- (void)audioSessionMediaServerTerminated:(RTCAudioSession *)session {
|
|
}
|
|
|
|
- (void)audioSessionMediaServerReset:(RTCAudioSession *)session {
|
|
}
|
|
|
|
- (void)audioSession:(RTCAudioSession *)session
|
|
didChangeCanPlayOrRecord:(BOOL)canPlayOrRecord {
|
|
_observer->OnCanPlayOrRecordChange(canPlayOrRecord);
|
|
}
|
|
|
|
- (void)audioSessionDidStartPlayOrRecord:(RTCAudioSession *)session {
|
|
}
|
|
|
|
- (void)audioSessionDidStopPlayOrRecord:(RTCAudioSession *)session {
|
|
}
|
|
|
|
- (void)audioSession:(RTCAudioSession *)audioSession
|
|
didChangeOutputVolume:(float)outputVolume {
|
|
_observer->OnChangedOutputVolume();
|
|
}
|
|
|
|
@end
|